Belgian Amiga Club - ADF Collection/BS1 part 54.zip/BS part 54/MultiFaXPRO_d1.adf/Install-MFax

Text File | 1992-12-22 | 6.4 KB | 326 lines

; script to install MultiFax professional

    ; set up a error cleanup routine

(onerror
    (makeassign "MultiFax_Disk" (safe))
)

(complete 0)

    ; just in case the installation was restarted

(makeassign "MultiFax_Disk" (safe))    ; start fresh

    ; see if this is really an update

    ; if update, be sure they want program in same place

    ; if not an update, get a location for program

(set mfax_dest
    (tackon
        (askdir
            (prompt "Auf welches Laufwerk oder in welches Verzeichnis soll "
                "MultiFax installiert werden (Help... beachten!) ?")
            (help "Das Verzeichnis \"MultiFax\" wird auf dem gewünschten "
                "Laufwerk oder in dem gewünschten Verzeichnis automatisch "
                "eingerichtet.")
            (default @default-dest)
        )
        "MultiFax"
    )
)

    ; now lock on to volume 'mfax'

(if (exists mfax_dest)
    (
    (set reinstall
        (askbool
            (prompt "Das Verzeichnis "MultiFax" existiert bereits! "
                "Soll die Installation trotzdem durchgeführt werden?")
            (help    "JA - Ein bereits eingerichtetes MultiFax professional "
                "wird überschrieben. Sollte es sich um die Version 2.0 "
                "handeln, dann wird das MultiFax professional dazugemischt. "
                "Bei einem bereits bestehenden MultiFax professional "
                "werden nur diejenigen Dateien überschrieben, die Sie "
                "in dem nächsten Menü auswählen und die bereits bestehen.\n\n"
                "NEIN - Die Installation wird nicht durchgeführt.")
            (choices "JA" "NEIN")
        )
    )
    (if (not reinstall)
        (exit)
    )
    )
)

(askdisk
    (prompt "Bitte legen Sie die Diskette \"MultiFax Programmdiskette\" in ein Laufwerk.")
    (help    "Die Programme des MultiFax werden auf Ihr System kopiert.")
    (dest  "MultiFax")
    (newname "MultiFax_Disk")
)

    ; make MFax drawer & icon if not there

(makedir mfax_dest (infos))

    ; at this point we have a valid destination, so we tell installer where
    ; the application will end up so the exit page will be correct -- also,
    ; the installation log file (if any) will be copied to the destination
(set @default-dest mfax_dest)

(set whichfiles
    (askoptions
        (prompt "Bitte wählen Sie die zu kopierenden Dateien:")
        (help    "Hiermit können Sie auch eine teilweise Installation durchführen. "
            "Für eine normalle Installation wählen Sie bitte alle Punkte an.")
        (choices "MultiFax-Module und Zeichensätze"
             "MultiFax-Druckertreiber"
             "Parameterdateien"
             "Sprachkataloge"
             "Beispielsfaxe"
             "ARexx Beispiele")

    )
)


(if    (in whichfiles 0)
; MultiFax Module und Zeichensätze
    (
        (copyfiles
            (source "MultiFax_Disk:MultiFax")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:Server")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:Spooler")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:Desk")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:Logbook")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:View")
            (dest mfax_dest)
        )
        (copyfiles
            (source "MultiFax_Disk:Config")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:MFRexx")
            (dest mfax_dest)
        )
        (copyfiles
            (source "MultiFax_Disk:Letterhead.IFF")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:MF_PICA.fnt")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:MF_ELITE.fnt")
            (dest mfax_dest)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:MF_FINE.fnt")
            (dest mfax_dest)
            (infos)
        )
    )
)

(complete 70)



(if    (in whichfiles 1)
; MultiFax-Druckertreiber
    (copyfiles
        (source "MultiFax_Disk:Devs/Printers/MultiFaxDriver")
        (dest "DEVS:Printers")
    )
)

(complete 75)

    ; Prüfen, ob in dem Parameter-Verzeichnis bereits eine Fax.INF ist.
(set nonew 0)
(if (not (exists (tackon mfax_dest "Parameter/Fax.INF")))
    (set nonew 1)
)

(makedir (tackon mfax_dest "Parameter")    (infos))

(if    (in whichfiles 2)
; Parameterdateien
    (
    (copyfiles
        (source "MultiFax_Disk:Parameter")
        (dest (tackon mfax_dest "Parameter"))
        (infos)
        (all)
    )
    )
)

    ; wenn noch keine Fax.INF in dem Parameter-Verzeichnis war, dann wird die
    ; alte Fax.INF aus dem Hauptverzeichnis dorthin kopiert, damit die alten
    ; Einstellungen des MultiFax 2.0 wenigstens ein Grundgerüst abgeben.
(if nonew
    (if( exists (tackon mfax_dest "Fax.INF"))
        (copyfiles
            (source (tackon mfax_dest "Fax.INF"))
            (dest (tackon mfax_dest "Parameter"))
        )
    )
)

(complete 80)

(tooltype
    (dest mfax_dest)
    (noposition)
)


   ;
   ; these libraries are necessary for PPage, make sure that they are there:
   ;

;;(if    (in whichfiles 3)
; Requester-Library
(set docopy 1)
(if    (= @user-level 2)
    (set docopy
        (askbool
            (prompt "Jetzt wird die req.library in das Verzeichnis LIBS: "
                "kopiert. Das geschieht aber nur, wenn in LIBS: noch "
                "keine req.library vorliegt oder die dort befindliche "
                "eine niedrigere Versionsnummer besitzt.\n\nSoll die "
                "library kopiert werden?")
            (help    "Eine möglicherweise dort befindliche req.library wird "
                "in LIBS: unter dem Namen \"req_old.library\" abgelegt, "
                "wenn Sie JA auswählen UND dort noch keine Library mit "
                "dem Namen \"req_old.library\" vorhanden ist.")
            (choices "JA" "NEIN")
        )
    )
)
(if docopy
    (
        (if    (exists "LIBS:req.library")
            (if    (not (exists "LIBS:req_old.library"))
                (copyfiles
                    (source "LIBS:req.library")
                    (dest "LIBS:req_old.library")
                    (optional)
                )
            )
        )
        (copylib
            (source "MultiFax_Disk:Libs/req.library")
            (dest "LIBS:")
        )
    )
)
;;)


(complete 85)

(makedir (tackon mfax_dest "Catalogs")    (infos))

(if    (in whichfiles 3)
; Sprachkataloge
    (copyfiles
        (source "MultiFax_Disk:Catalogs")
        (dest (tackon mfax_dest "Catalogs"))
        (infos)
        (all)
    )
)


(complete 90)

(makedir (tackon mfax_dest "Output")    (infos))

(makedir (tackon mfax_dest "Input")    (infos))


(if    (in whichfiles 4)
; Beispielsfaxe
    (
        (copyfiles
            (source "MultiFax_Disk:Output")
            (dest (tackon mfax_dest "Output"))
            (all)
            (infos)
        )
        (copyfiles
            (source "MultiFax_Disk:Input")
            (dest (tackon mfax_dest "Input"))
            (all)
            (infos)
        )
    )
)

(complete 95)

(copyfiles
    (source "MultiFax_Disk:ARexx.dok")
    (dest mfax_dest)
    (infos)
)

(if    (in whichfiles 5)
; ARexx Beispiele
    (
        (copyfiles
            (source "MultiFax_Disk:Rexx")
            (dest (tackon mfax_dest "Rexx"))
            (all)
            (infos)
        )
    )
)

    ; modify S:User-Startup

    ; reinitialize assigns

(complete 100)

    ; cleanup

(makeassign "MultiFax_Disk" (safe))

    ; this is not strictly necessary, but doesn't hurt -- there is always
    ; a default (exit) at the end of any script

(exit)